下面，我們再來學習字符型液晶模塊TC1602的使用，接口單片機是at89s51。
【1602液晶模塊簡介】
字符型型液晶是一種用5×7點陣圖形來顯示字符的液晶顯示器，根據顯示的容量可以分為1行16個字、2行16個字、2行20個字等，最常用的為2行16個字，即我們馬上要學習的1602液晶模塊，下面(圖1)就是TC1602液晶模塊的正面和反面照片。
 |
||
|
圖1： 《TC1602液晶模塊》 |
||
液晶屏顯示模塊與數碼管相比，它顯得更為專業、漂亮。液晶顯示屏以其微功耗、體積小、顯示內容豐富、超薄輕巧、使用方便等諸多優點，在儀器儀表、電子設備、家用電器等低功耗應用系統中得到越來越廣泛的應用，使這些電子設備的人機界面變得越來越直觀形象，目前已廣泛應用于電子表、計算器、IC卡電話機、液晶電視機、便攜式電腦、掌上型電子玩具、復印機、傳真機等許多方面。本站S51增強型實驗板配套的液晶模塊是TC1602EL字符型液晶模塊(帶背光)，它是目前使用最為廣泛的液晶屏之一，相信你學會了對它的使用，那你對其它的液晶屏的使用也能得心應手，畢竟基本原理都差不多。
本站使用帶背光的液晶模塊TC1602EL，TC1602EL采用標準的16腳接口，其引腳功能如下：
第1腳：VSS為電源地，接GND。
第2腳：VDD接5V正電源。
第3腳：VL為液晶顯示器對比度調整端，接正電源時對比度最弱，接地電源時對比度最高，對比度過高時會產生“鬼影”，使用時可以通過一個10K的電位器調整對比度。
第4腳：RS為寄存器選擇，高電平時選擇數據寄存器、低電平時選擇指令寄存器。
第5腳：RW為讀寫信號線，高電平時進行讀操作，低電平時進行寫操作。當RS和RW共同為低電平時可以寫入指令或者顯示地址，當RS為低電平RW為高電平時可以讀忙信號，當RS為高電平RW為低電平時可以寫入數據。
第6腳：E端為使能端，當E端由高電平跳變成低電平時，液晶模塊執行命令。
第7～14腳：D0～D7為8位雙向數據線。
第15腳：BLA背光電源正極(+5V)輸入引腳。
第16腳：BLK背光電源負極，接GND。
|
注意：液晶模塊背光須消耗電流約為50mA左右，S51增強型實驗板上設計了DIP微動開關來控制背光的開關，如右圖所示，當實驗板上的DIP開關(第3位)撥打到ON狀態時，液晶背光顯示，撥到OFF狀態時，背光關閉。 |
 |
TC1602液晶模塊內帶標準字庫，內部的字符發生存儲器（CGROM）已經存儲了192個5×7點陣字符，32個5×10點陣字符。另外還有字符生成RAM（CGRAM）512字節，供用戶自定義字符。如表1所示，這些字符有：阿拉伯數字、英文字母的大小寫、常用的符號、和日文假名等，每一個字符都有一個固定的代碼，比如大寫的英文字母“A”的代碼是01000001B（41H），顯示時模塊把地址41H中的點陣字符圖形顯示出來，我們就能看到字母“A”。
 |
|
表1： CGROM和CGRAM中字符代碼與字符圖形對應關系 |
1602液晶模塊內部的控制器共有11條控制指令，如表2所示。它的讀寫操作、屏幕和光標的操作都是通過指令編程來實現的。（說明：1為高電平、0為低電平）
 |
|
表2： 1602液晶模塊內部的控制器共有11條控制指令 |
指令1：清顯示，指令碼01H,光標復位到地址00H位置
指令2：光標復位，光標返回到地址00H
指令3：光標和顯示模式設置 I/D：光標移動方向，高電平右移，低電平左移 S:屏幕上所有文字是否左移或者右移。高電平表示有效，低電平則無效
指令4：顯示開關控制。 D：控制整體顯示的開與關，高電平表示開顯示，低電平表示關顯示 C：控制光標的開與關，高電平表示有光標，低電平表示無光標 B：控制光標是否閃爍，高電平閃爍，低電平不閃爍
指令5：光標或顯示移位 S/C：高電平時移動顯示的文字，低電平時移動光標
指令6：功能設置命令 DL：高電平時為4位總線，低電平時為8位總線 N：低電平時為單行顯示，高電平時雙行顯示 F: 低電平時顯示5x7的點陣字符，高電平時顯示5x10的點陣字符
指令7：字符發生器RAM地址設置
指令8：DDRAM地址設置
指令9：讀忙信號和光標地址 BF：為忙標志位，高電平表示忙，此時模塊不能接收命令或者數據，如果為低電平表示不忙。
指令10：寫數據
指令11：讀數據
下面是TC1602液晶模塊的一些主要技術參數：
1、邏輯工作電壓（VDD）：+4.5 ～ +5.5V
2、LCD驅動電壓（VDD - VL）：+4.5 ～ +13.0V
3、工作溫度（Ta）： 0 ～ 60°C（常溫）/-20 ～ 75 °C（寬溫）
4、工作電流： < 2.0mA
5、屏幕視域尺寸： 62.5 × 16.1mm
【TC1602EL液晶模塊應用編程】
TC1602EL液晶顯示模塊可以和51系列單片機直接接口，下面就是S51增強型實驗板的液晶接口電路(圖2)。
 |
|
圖2 |
液晶顯示模塊是一個慢顯示器件，所以在執行每條指令之前一定要確認模塊的忙標志為低電平，表示不忙，否則此指令失效。要顯示字符時要先輸入顯示字符地址，也就是告訴模塊在哪里顯示字符，表3是TC1602EL液晶模塊的內部顯示地址。
 |
|
表3：1602液晶內部顯示地址 |
比如第二行第一個字符的地址是40H，那么是否直接寫入40H就可以將光標定位在第二行第一個字符的位置呢？這樣不行，因為寫入顯示地址時要求最高位D7恒定為高電平1所以實際寫入的數據應該是01000000B（40H）＋10000000B（80H）＝11000000B（C0H），下面就是在1602液晶模塊第一行第1個字符位置顯示字母“A”程序。
;*******************TC1602液晶模塊字符顯示試驗**********************************
;******** 在1602液晶模塊第一行第1個字符位置顯示字母“A”程序 ********
RS EQU P3.4
RW EQU P3.5
E EQU P3.6
ORG 0000H
AJMP START
ORG 0033H
START: MOV SP,#60H
MAIN: LCALL DELAY ;判斷液晶忙狀態？
ACALL ENABLE
MOV P1,#00000001B ;寫指令01H,清屏
ACALL ENABLE
MOV P1,#00111000B ;寫指令38H,設定LCD為16×2顯示，5×7點陣，8位數據接口
ACALL ENABLE
MOV P1,#00001111B ;寫指令0FH,顯示ON,光標ON,閃爍ON
ACALL ENABLE
MOV P1,#00000110B ;寫指令06H,文字不動，光標自動右移
ACALL ENABLE
MOV P1,#80H ;第一行第1個字符地址
ACALL ENABLE
MOV P1,#01000001B ;字母A的代碼(#41H)
SETB RS ;RS=1
CLR RW ;RW=0
CLR E ;E=0
ACALL DELAY ;判斷液晶忙狀態？
SETB E ;E=1
AJMP $
;-----------------
ENABLE: CLR RS ;寫入控制命令的子程序
CLR RW
CLR E
ACALL DELAY
SETB E
RET
;-----------------
DELAY: MOV P1,#0FFH ;判斷液晶顯示器是否忙的子程序
CLR RS
SETB RW
CLR E
NOP
SETB E
JB P1.7,DELAY ;如果為高電平表示忙就循環等待
RET
END
程序在開始時對液晶模塊功能進行了初始化設置，約定了顯示格式。注意顯示字符時光標是自動右移的，無需人工干預，每次輸入指令都先調用判斷液晶模塊是否忙的子程序DELAY，然后輸入顯示位置的地址80H（第一行第1字符），最后輸入要顯示的字符"A"的代碼41H，顯示效果下面如圖3所示。
|
圖3： 1602液晶顯示一個字符“A” |
前面我們進行了液晶顯示一個字符“A”的實驗，接下來再來編一個稍復雜點的多字符顯示程序，相信你有了第一個程序的經驗，下面的程序也就沒有什么難度了，畢竟程序都差不多。下面程序實現兩行顯示：第1行顯示"welcme!"，第2行顯示"www.ourmpu.com"。顯示效果見下圖4。
;******** TC1602液晶模塊字符顯示試驗單片機匯編程序 ********
;******** 第一行顯示“welcme! ********
;******** 第二行顯示“www.ourmpu.com” ********
RS EQU P3.4
RW EQU P3.5
E EQU P3.6
ORG 0000H
AJMP START
ORG 0033H
START: MOV SP,#60H
MAIN: LCALL DELAY ;延時一段時間
MOV P1,#01H ;寫指令01H,清屏
LCALL ENABLE
MOV P1,#38H ;寫指令38H,設定LCD為16*2顯示，5*7點陣，8位數據接口
LCALL ENABLE
MOV P1,#0FH ;寫指令0FH,顯示ON,光標ON,閃爍ON
LCALL ENABLE
MOV P1,#06H ;寫指令06H,光標輸入方式增量移位
LCALL ENABLE
MOV P1,#80H ;第一行起始字符地址
LCALL ENABLE
MOV DPTR,#TABLE1 ;第一行顯示字符表頭地址
LCALL DISP ;顯示第一行數據
MOV P1,#0C0H ;第二行起始字符地址
LCALL ENABLE
MOV DPTR,#TABLE2 ;第二行顯示字符表頭地址
LCALL DISP ;顯示第二行數據
AJMP MAIN ;返回主程序循環
;-----------------
ENABLE: CLR RS ;寫指令子程序(請參照1602LCD使用說明書)
CLR RW
CLR E
LCALL DELAY
SETB E
RET
;-----------------
DISP: MOV R1,#16 ;準備顯示一行16個字符
LOOP: MOV A,#00H ;將ACC清零
MOVC A,@A+DPTR ;查表取得要顯示的數據
LCALL DISP1 ;寫入一個數據
INC DPTR ;數據表指針加1,準備取下一個數據
DJNZ R1,LOOP ;一行沒有顯示完就繼續
RET
;-----------------
DISP1: MOV P1,A ;寫1字節數據到顯示端口
SETB RS ;寫數據時序(請參照1602LCD使用說明書)
CLR RW
CLR E
LCALL DELAY
SETB E
RET
;-----------------
DELAY: MOV R7,#255 ;延時子程序
D1: MOV R6,#255
D2: DJNZ R6,D2
DJNZ R7,D1
RET
TABLE1: DB " welcome! "
TABLE2: DB " www.ourmpu.com "
END
|
圖4：《單片機驅動1602液晶多字符顯示效果》 |
至此，我們學習了字符型液晶模塊1602在S51增強型實驗板上的應用及編程，相信大家看到一定這里都有點累了吧！現在回過頭來再看看，其實液晶模塊編程也并沒有想像的那么高深、難學！現在，你就可以充分發揮你聰明才智，按自己的意愿及要求來編寫各種各樣的顯示應用程序了，如萬年歷時鐘、溫度計、頻率計等，可以充分發揮你的想象達到你所需要的各種顯示效果。最后，讓我們再欣賞一個基于S51增強型實驗板開發的1602液晶模塊高精度(4位小數)數字溫度計的圖片吧，見下圖5所示。
|
圖5：1602液晶顯示DS18B20高精度(4位小數)測溫效果 |
