在知識(shí)比賽中， 特別是做搶答題目的時(shí)候， 在搶答過程中，為了知道哪一組或哪一位選手先答題，必須要設(shè)計(jì)一個(gè)系統(tǒng)來完成這個(gè)任務(wù)。如果在搶答中，靠視覺是很難判斷出哪組先答題。利用單片機(jī)系統(tǒng)來設(shè)計(jì)搶答器，使以上問題得以解決，即使兩組的搶答時(shí)間相差幾微秒，也可分辨出哪組優(yōu)先答題。本文主要介紹了單片機(jī)搶答器設(shè)計(jì)及工作原理，以及它的實(shí)際用途。 ! 系統(tǒng)工作原理本系統(tǒng)采用8051單片機(jī)作為核心。控制系統(tǒng)的四個(gè)模塊分別為：存儲(chǔ)模塊、顯示模塊、語音模塊、搶答開關(guān)模塊。該搶答器系統(tǒng)通過開關(guān)電路四個(gè)按鍵輸入搶答信號(hào)；利用語音芯片ISD1420 完成語音的錄放功能； 利用存儲(chǔ)程序； 利用一個(gè)數(shù)碼管來完成顯示功能。工作時(shí)，用按鍵通過開關(guān)電路輸入各路的搶答信號(hào)，經(jīng)單片機(jī)的處理， 輸出控制信號(hào)， 控制數(shù)碼管和語音芯片工作。在數(shù)碼管上顯示哪一組先答題，并通過語音系統(tǒng)讀出 “第9組請(qǐng)答題”，從而實(shí)現(xiàn)整個(gè)搶答過程。搶答器程序在本文下放給了一個(gè)還需要大家來完善，如果你有更好的設(shè)計(jì)請(qǐng)聯(lián)系我（www.izizhuan.cn首頁有聯(lián)系方式),系統(tǒng)的原理圖如下圖 
下面這個(gè)單片機(jī)搶答器設(shè)計(jì)程序，大家測(cè)試一下，有什么問題可直接與我聯(lián)系
*
1、如果想調(diào)節(jié)搶答時(shí)間或答題時(shí)間,按"搶答時(shí)間調(diào)節(jié)"鍵或"答題時(shí)間調(diào)節(jié)"鍵進(jìn)入調(diào)節(jié)狀態(tài),此時(shí)會(huì)顯示現(xiàn)在設(shè)定的搶答時(shí)間或回答時(shí)間值,如想加一秒按一下"加1s"鍵,如果想減一秒按一下"-1s"鍵，時(shí)間LED上會(huì)顯示改變后的時(shí)間，調(diào)整范圍為0s~99s, 0s時(shí)再減1s會(huì)跳到99，99s時(shí)再加1s會(huì)變到0s。
2、主持人按"搶答開始"鍵，會(huì)有提示音，并立刻進(jìn)入搶答倒計(jì)時(shí)（預(yù)設(shè)15s搶答時(shí)間），如有選手搶答，會(huì)有提示音，并會(huì)顯示其號(hào)數(shù)并立刻進(jìn)入回答倒計(jì)時(shí)（預(yù)設(shè)10s搶答時(shí)間），不進(jìn)行搶答查詢，所以只有第一個(gè)按搶答的選手有效。倒數(shù)時(shí)間到小于5s會(huì)每秒響一下提示音。
3、如倒計(jì)時(shí)期間，主持人想停止倒計(jì)時(shí)可以隨時(shí)按"停止"按鍵，系統(tǒng)會(huì)自動(dòng)進(jìn)入準(zhǔn)備狀態(tài)，等待主持人按"搶答開始"進(jìn)入下次搶答計(jì)時(shí)。
4、如果主持人未按"搶答開始"鍵，而有人按了搶答按鍵，犯規(guī)搶答，LED上不斷閃爍FF和犯規(guī)號(hào)數(shù)并響個(gè)不停，直到按下"停止" 鍵為止。
*******************************************************************************************
P1.0為開始搶答，P1.7為停止，p1.1-p1.6為六路搶答輸入 數(shù)碼管段選P0口，位選P2口，蜂鳴器輸出為P3.6口
*******************************************************************************************
;============
OK EQU 20H ;搶答開始標(biāo)志位;將P1口與P2口互換，P3.0-P1.0,P3.1-P1.7
RING EQU 22H ;響鈴標(biāo)志位
ORG 0000H
AJMP MAIN
ORG 0003H
AJMP INT0SUB
ORG 000BH
AJMP T0INT
ORG 0013H
AJMP INT1SUB
ORG 001BH
AJMP T1INT
ORG 0040H
;===============-
;單片機(jī)搶答器主程序設(shè)計(jì)
;================
MAIN: MOV R1,#0FH ;初設(shè)搶答時(shí)間為15s
MOV R2,#0AH ;初設(shè)答題時(shí)間為10s
MOV TMOD,#11H ;設(shè)置未定時(shí)器/模式1
MOV TH0,#0F0H
MOV TL0,#0FFH ;越高發(fā)聲頻率越高,越尖
MOV TH1,#3CH
MOV TL1,#0B0H ;50ms為一次溢出中斷
SETB EA
SETB ET0
SETB ET1
SETB EX0
SETB EX1 ;允許四個(gè)中斷,T0/T1/INT0/INT1
CLR OK
CLR RING
SETB TR1
SETB TR0 ;一開始就運(yùn)行定時(shí)器,以開始顯示FFF.如果想重新計(jì)數(shù),重置TH1/TL1就可以了
;=====查詢程序=====
START: MOV R5,#0BH
MOV R4,#0BH
MOV R3,#0BH
ACALL DISPLAY ;未開始搶答時(shí)候顯示FFF
JB P1.0,NEXT ;ddddddd
ACALL DELAY
JB P1.0,NEXT ;去抖動(dòng),如果"開始鍵"按下就向下執(zhí)行,否者跳到非法搶答查詢
ACALL BARK ;按鍵發(fā)聲
MOV A,R1
MOV R6,A ;送R1->R6,因?yàn)镽1中保存了搶答時(shí)間
SETB OK ;搶答標(biāo)志位,用于COUNT只程序中判斷是否查詢搶答
MOV R3,0AH ;搶答只顯示計(jì)時(shí),滅號(hào)數(shù)
AJMP COUNT ;進(jìn)入倒計(jì)時(shí)程序,"查詢有效搶答的程序"在COUNT里面
NEXT: JNB P1.1,FALSE1
JNB P1.2,FALSE2
JNB P1.3,FALSE3
JNB P1.4,FALSE4
JNB P1.5,FALSE5
JNB P1.6,FALSE6
AJMP START
;=====非法搶答處理程序=====
FALSE1: ACALL BARK ;按鍵發(fā)聲
MOV R3,#01H
AJMP ERROR
FALSE2: ACALL BARK
MOV R3,#02H
AJMP ERROR
FALSE3: ACALL BARK
MOV R3,#03H
AJMP ERROR
FALSE4: ACALL BARK
MOV R3,#04H
AJMP ERROR
FALSE5: ACALL BARK
MOV R3,#05H
AJMP ERROR
FALSE6: ACALL BARK
MOV R3,#06H
AJMP ERROR
;=====INT0(搶答時(shí)間R1調(diào)整程序)=====
INT0SUB:MOV A,R1
MOV B,#0AH
DIV AB
MOV R5,A
MOV R4,B
MOV R3,#0AH
ACALL DISPLAY ;先在兩個(gè)時(shí)間LED上顯示R1
JNB P3.4,INC0 ;P3.4為+1s鍵,如按下跳到INCO
JNB P3.5,DEC0 ;P3.5為-1s鍵,如按下跳到DECO
JNB P1.7,BACK0 ;P3.1為確定鍵,如按下跳到BACKO
AJMP INT0SUB
INC0: MOV A,R1
CJNE A,#63H,ADD0 ;如果不是99,R2加1,如果加到99了,R1就置0，重新加起。
MOV R1,#00H
ACALL DELAY1
AJMP INT0SUB
ADD0: INC R1
ACALL DELAY1
AJMP INT0SUB
DEC0: MOV A,R1
JZ SETR1 ;如果R1為0, R1就置99，
DEC R1
ACALL DELAY1
AJMP INT0SUB
SETR1: MOV R1,#63H
ACALL DELAY1
AJMP INT0SUB
BACK0: RETI
;=====INT1(回答時(shí)間R2調(diào)整程序)=====
INT1SUB:
MOV A,R2
MOV B,#0AH
DIV AB
MOV R5,A
MOV R4,B
MOV R3,#0AH
ACALL DISPLAY
JNB P3.4,INC1
JNB P3.5,DEC1
JNB P1.7,BACK1
AJMP INT1SUB
INC1: MOV A,R2
CJNE A,#63H,ADD1
MOV R2,#00H
ACALL DELAY1
AJMP INT1SUB
ADD1: INC R2
ACALL DELAY1
AJMP INT1SUB
DEC1: MOV A,R2
JZ SETR2
DEC R2
ACALL DELAY1
AJMP INT1SUB
SETR2: MOV R2,#63H
ACALL DELAY1
AJMP INT1SUB
BACK1: RETI
;=====倒計(jì)時(shí)程序(搶答倒計(jì)時(shí)和回答倒計(jì)時(shí)都跳到改程序)=====
COUNT: MOV R0,#00H ;重置定時(shí)器中斷次數(shù)
MOV TH1,#3CH
MOV TL1,#0B0H ;重置定時(shí)器
RECOUNT:
MOV A,R6 ;R6保存了倒計(jì)時(shí)的時(shí)間,之前先將搶答時(shí)間或回答時(shí)間給R6
MOV B,#0AH
DIV AB ;除十分出個(gè)位/十位
MOV 30H,A ;十位存于(30H)
MOV 31H,B ;個(gè)位存于(31H)
MOV R5,30H ;取十位
MOV R4,31H ;取個(gè)位
MOV A,R6
SUBB A,#07H
JNC LARGER ;大于5s跳到LARGER,小于等于5s會(huì)提醒
MOV A,R0
CJNE A,#0AH,FULL;1s中0.5s向下運(yùn)行
CLR RING
AJMP CHECK
FULL: CJNE A,#14H,CHECK;下面系1s的情況,響并顯示號(hào)數(shù)并清R0,重新計(jì)
SETB RING
MOV A,R6
JZ QUIT ;計(jì)時(shí)完畢
MOV R0,#00H
DEC R6 ;一秒標(biāo)志減1
AJMP CHECK
LARGER:
MOV A,R0
CJNE A,#14H,CHECK;如果1s向下運(yùn)行,否者跳到查"停/顯示"
DEC R6 ;計(jì)時(shí)一秒R6自動(dòng)減1
MOV R0,#00H
CHECK: JNB P1.7,QUIT ;如按下停止鍵退出
ACALL DISPLAY
JB OK,ACCOUT ;如果是搶答倒計(jì)時(shí),如是則查詢搶答,否者跳過查詢繼續(xù)倒數(shù)(這里起到鎖搶答作用)
AJMP RECOUNT
ACCOUT:JNB P1.1,TRUE1
JNB P1.2,TRUE2
JNB P1.3,TRUE3
JNB P1.4,TRUE4
JNB P1.5,TRUE5
JNB P1.6,TRUE5
AJMP RECOUNT
QUIT: CLR OK ;如果按下了"停止鍵"執(zhí)行的程序
CLR RING
AJMP START
;=====正常搶答處理程序=====
TRUE1: ACALL BARK ;按鍵發(fā)聲
MOV A,R2
MOV R6,A ;搶答時(shí)間R2送R6
MOV R3,#01H
CLR OK ;因?yàn)榇痤}的計(jì)時(shí)不再查詢搶答,所以就鎖了搶答
AJMP COUNT
TRUE2: ACALL BARK;
MOV A,R2
MOV R6,A
MOV R3,#02H
CLR OK
AJMP COUNT
TRUE3: ACALL BARK;
MOV A,R2
MOV R6,A
MOV R3,#03H
CLR OK
AJMP COUNT
TRUE4: ACALL BARK;
MOV A,R2
MOV R6,A
MOV R3,#04H
CLR OK
AJMP COUNT
TRUE5: ACALL BARK;
MOV A,R2
MOV R6,A
MOV R3,#05H
CLR OK
AJMP COUNT
TRUE6: ACALL BARK;
MOV A,R2
MOV R6,A
MOV R3,#06H
CLR OK
AJMP COUNT
;=====犯規(guī)搶答程序=====
ERROR: MOV R0,#00H
MOV TH1,#3CH
MOV TL1,#0B0H
MOV 34H,R3 ;犯規(guī)號(hào)數(shù)暫存與(34H)
HERE: MOV A,R0
CJNE A,#0AH,FLASH ;0.5s向下運(yùn)行->滅并停響
CLR RING
MOV R3,#0AH
MOV R4,#0AH
MOV R5,#0AH ;三燈全滅
AJMP CHECK1
FLASH: CJNE A,#14H,CHECK1 ;下面系1s的情況,響并顯示號(hào)數(shù)并清R0,重新計(jì)
SETB RING
MOV R0,#00H
MOV R3,34H ;取回號(hào)數(shù)
MOV R5,#0BH
MOV R4,#0BH ;顯示FF和號(hào)數(shù)
AJMP CHECK1
CHECK1:JNB P1.7,QUIT1
ACALL DISPLAY
AJMP HERE
QUIT1: CLR RING
CLR OK
AJMP START
;=====單片機(jī)搶答器顯示程序=====
DISPLAY:
MOV DPTR,#DAT1 ;查表顯示程序,利用P0口做段選碼口輸出/P2低三位做位選碼輸出,
MOV A,R5
MOVC A,@A+DPTR
MOV P2,#01H
MOV P0,A
ACALL DELAY
MOV DPTR,#DAT2
MOV A,R4
MOVC A,@A+DPTR
MOV P2,#02H
MOV P0,A
ACALL DELAY
MOV A,R3
MOVC A,@A+DPTR
MOV P2,#04H
MOV P0,A
ACALL DELAY
RET
DAT1:DB 00H,06h,5bh,4fh,66h,6dh,7dh,07h,7fh,6fh,00H,71H
;"滅","1","2","3","4","5","6","7","8","9","滅","F"
DAT2:DB 3fh,06h,5bh,4fh,66h,6dh,7dh,07h,7fh,6fh,00H,71H
;第一個(gè)為零,其他與上相同,因?yàn)槭蝗绻麨榱泔@示熄滅
;====加減時(shí)間延時(shí)(起到不會(huì)按下就加N個(gè)數(shù))======
DELAY1: MOV 35H,#08H
LOOP0: ACALL DISPLAY
DJNZ 35H,LOOP0
RET
;=====延時(shí)(顯示和去抖動(dòng)用到)=====
DELAY: MOV 32H,#12H
LOOP: MOV 33H,#0AFH
LOOP1: DJNZ 33H,LOOP1
DJNZ 32H,LOOP
RET
;=====發(fā)聲程序=====
BARK: SETB RING
ACALL DELAY1
ACALL DELAY1
CLR RING ;按鍵發(fā)聲
RET
;=====TO溢出中斷(響鈴程序)=====
T0INT: MOV TH0,#0ECH
MOV TL0,#0FFH
JNB RING,OUT;
CPL P3.6 ;RING標(biāo)志位為1時(shí)候P3.6口不短取反使喇叭發(fā)出一定頻率的聲音
OUT: RETI
;=====T1溢出中斷(計(jì)時(shí)程序)=====
T1INT: MOV TH1,#3CH
MOV TL1,#0B0H
INC R0
RETI
END